# The uhhm Arch registry package, built by .gitea/workflows/release.yml
# from the release tarballs (the CI pins pkgver and the sums). For a
# from-source build (AUR style) see ../PKGBUILD.
pkgname=varde
pkgver=0.1.3
pkgrel=1
pkgdesc="Content-addressed blob mirror daemon on iroh"
arch=('x86_64' 'aarch64')
url="https://project.uhhm.no/uhhm/varde"
license=('MIT OR Apache-2.0')
depends=('gcc-libs' 'glibc')
optdepends=('networkmanager: metered-connection detection')
backup=('etc/varde/config.toml')
install=varde.install
options=('!strip' '!debug')
source_x86_64=("varde-${pkgver}-x86_64-unknown-linux-gnu.tar.gz")
source_aarch64=("varde-${pkgver}-aarch64-unknown-linux-gnu.tar.gz")
sha256sums_x86_64=('SKIP')
sha256sums_aarch64=('SKIP')

package() {
  cd "varde-${pkgver}-${CARCH}-unknown-linux-gnu"
  install -Dm755 bin/varde-daemon "$pkgdir/usr/bin/varde-daemon"
  install -Dm755 bin/varde-ctl "$pkgdir/usr/bin/varde-ctl"

  install -Dm644 systemd/varde.service "$pkgdir/usr/lib/systemd/system/varde.service"
  install -Dm644 systemd/varde.socket "$pkgdir/usr/lib/systemd/system/varde.socket"
  install -Dm644 systemd/user/varde.service "$pkgdir/usr/lib/systemd/user/varde.service"
  install -Dm644 systemd/user/varde.socket "$pkgdir/usr/lib/systemd/user/varde.socket"
  # The per-user socket is on for every session, the way PipeWire's
  # is: it costs nothing until an app connects, and then the daemon
  # starts by socket activation. The system daemon stays opt-in.
  install -dm755 "$pkgdir/usr/lib/systemd/user/sockets.target.wants"
  ln -s ../varde.socket "$pkgdir/usr/lib/systemd/user/sockets.target.wants/varde.socket"

  install -Dm644 config.toml.example "$pkgdir/etc/varde/config.toml"
  install -Dm644 man/varde.8 "$pkgdir/usr/share/man/man8/varde.8"
  install -Dm644 man/varde-ctl.1 "$pkgdir/usr/share/man/man1/varde-ctl.1"
  install -Dm644 LICENSE-MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
  install -Dm644 LICENSE-APACHE "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
}